Isolde-Kurz-Gymnasium Reutlingen

Abiturprüfung 1999 'Pilotprojekt Mobiles Klassenzimmer'

 

Leistungskurs, Aufgabenvorschlag 1

Zwei Flugzeuge starten von benachbarten Flugplätzen. Sie bewegen sich gleichmäßig beschleunigt gemäß r(t) = a*t^2/2 +r0. Dabei ist a der Beschleunigungsvektor und r0 der Ortsvektor zur Zeit t = 0 ('Startpunkt'). Die Anfangsgeschwindigkeit ist 0.

(Längen- und Zeiteinheiten werden im folgenden nicht angegeben und auch bei den Antworten nicht verlangt. Man kann aber bei der Längeneinheit an Kilometer und bei der Zeiteinheit an Minute denken.)

a) Welche geometrischen Orte werden durch r(t) beschrieben?

Ein Flugplatz (O) befinde sich im Ursprung des gemeinsamen Koordinatensystems, der andere in P(2 | 6 | 0). Für die Richtungsvektoren der Beschleunigungen gelte a1 = [0,2,1] (Start in O) und a2 = [-1, -3, 1] (Start in P).

Untersuchen Sie den Abstand der beiden Flugzeuge in Abhängigkeit von der Zeit. (Über die Form der Kurve lassen sich auch ohne Ableitung qualitative Aussagen machen. Die Untersuchung der Abstandsfunktion sollte auch negative Zeiten beinhalten.)

Wenn das Flugzeug in P mit anderen Beträgen der Beschleunigung (aber in der oben gegebenen Richtung) startet, gibt es einen kleinstmöglichen Abstand zwischen den Flugzeugen. Zu welchem Zeitpunkt wird dieser kleinstmögliche Abstand erreicht?

Für welchen Beschleunigungsvektor a2 tritt dieser Fall ein?

b) Dem in P startenden Flugzeug werden nun auch andere Startrichtungen freigegeben, und zwar so, daß der Richtungsvektor der Beschleunigung a2 in der y-Komponente beliebige Werte annehmen kann, also a2 = [-1, ay, 1]. Zeigen Sie, daß das Quadrat des Abstands nun durch folgende Schar dargestellt werden kann:

[Maple Math]

Zeichnen Sie diese Schar für geeignete Werte von t und ay.

Was läßt sich nun über die Abstandsfunktion aussagen?

Untersuchen Sie insbesondere:

- Für welche Werte von ay nimmt die Entfernung der Flugzeuge nach dem Start monoton zu?

- Für welchen Wert von ay haben die Piloten am längsten Zeit, bis der kleinste Abstand erreicht wird und wie groß ist in diesem Fall der kleinste Abstand?

- Kann es einen Zusammenstoß geben, wenn ay variiert wird? Wenn ja: Wann und wo?

c) Für die Beschleunigung des in P startenden Flugzeugs gelte: a2 = [-1,-1,1]. Die Sichtweite beträgt 1.

Wieviel Zeit bleibt den Piloten vom ersten Sichtkontakt bis der kleinste Abstand erreicht ist?

Unter welchen Winkeln (bezogen auf die eigene Flugrichtung) sieht der Pilot des in P startenden Flugzeugs das andere Flugzeug? Wie läßt sich das Ergebnis interpretieren?

Zeichnen Sie eine Schar von Strecken, die die beiden Flugzeuge verbinden. Welche Eigenschaft haben diese Strecken (mit Begründung)?

>

Anmerkung zur Korrektur: Es handelt sich bei der 'Feinverteilung' der VP eher um einen Erwartungshorizont, da die Aufgabe insgesamt der wichtigsten Intention unseres Projekts folgt: 'Mathematischer Erörterungsaufsatz'.

>

a)

Welche geometrischen Orte werden durch r(t) beschrieben?

Parameter t quadratisch, nur positive Vielfache von a werden zu r0 addiert: Eine Halbgerade mit dem Ende in r0 und der Richtung a.

>

> # 1VP

>

> restart:with(linalg):

Warning, new definition for norm
Warning, new definition for trace

Aufstellen der Ortsfunktionen (z.B. in Termform):

> r1:=a1*t^2/2;

[Maple Math]

> r2:=a2*t^2/2+p;

[Maple Math]

Daten:

> a1:=[0,2,1]:a2:=[-1,-3,1]:p:=[2,6,0]:

>

Abstandsquadrat (Im folgenden gilt immer: Mit einer entsprechenden Bemerkung (zur Monotonie der Wurzelfunktion) kann immer das Quadrat des Abstands verwendet werden):

> d2:=dotprod(r1-r2,r1-r2,orthogonal);

[Maple Math]

>

> # 2VP

>

Eine erste Zeichnung zur Übersicht

> plot(sqrt(d2),t=-3..4,0..10);

[Maple Plot]

>

> # 1VP

>

>

Die Symmetrie in der Bewegung bedeutet, daß für negative Zeiten die Flugzeuge eine Bewegung in umgekehrte Richtung durchführen würden (landen).

>

Daß die Kurve diese Form haben muß, sieht man dem Quadrat des Abstands an:

> collect(expand(d2),t);

[Maple Math]

>

Die Kurve zeigt ein Maximum für t = 0 sowie zwei zu t = 0 symmetrische Minima:

>

> # 1VP

>

Notwendig

> textr:=solve(diff(d2,t));

[Maple Math]

> evalf(%);

[Maple Math]

>

Hinreichend:

> subs(t=textr[1],diff(d2,t$2)),subs(t=textr[2],diff(d2,t$2)),subs(t=textr[3],diff(d2,t$2));

[Maple Math]

(oder Symmetrie)

>

Kleinster Abstand:

> subs(t=textr[2],sqrt(d2));

[Maple Math]

> evalf(%);

[Maple Math]

>

> # 3VP

>

>

Wenn das Flugzeug in P mit anderen Beträgen der Beschleunigung (aber in der oben gegebenen Richtung) startet, gibt es einen kleinstmöglichen Abstand zwischen den Flugzeugen. Zu welchem Zeitpunkt wird dieser kleinstmögliche Abstand erreicht?

Geometrisch handelt es sich um den Abstand zweier windschiefer Geraden (der Flugzeugbahnen). Es ist aber dem Problem weit besser angepaßt, das Minimum einer Funktion von zwei Veränderlichen (|a2| und t) zu suchen.

Neuer Ortsvektor für das in P startende Flugzeug mit variablem Betrag des Richtungsvektors:

> r2m:=a*[-1,-3,1]/2*t^2+p; #oder: r2m:=EMIL*[-1,-3,1]*t^2+p;

[Maple Math]

Abstandsquadrat als Funktion von a und t:

> d2m:=dotprod(r1-r2m,r1-r2m,orthogonal);

[Maple Math]

(Fehlerquelle wäre, mit den gleichen Namen r2 und d2 zu rechnen. Im Prinzp kann man mit jedem Vielfachen des ursprünglichen a2 rechnen. Der Faktor 1/2 ist nur für die physikalisch korrekte Beschleunigung erforderlich und es sollte nicht als Fehler gewertet werden, wenn er fehlt oder nachträglich nicht wieder eingeführt wird. )

>

Notwendige Bedingung für Extrema:

> solve({diff(d2m,a),diff(d2m,t)});

[Maple Math]

> allvalues({%});

[Maple Math]

t = 0 kommt nicht in Frage (Maximum, s.o.) und negative Zeiten sind hier nicht gefragt, also:

>

> tm:=4*sqrt(30)/15;

[Maple Math]

> evalf(%);

[Maple Math]

>

> # Zusatzpunkt für weitergehende Erörterungen möglich, z.B.:

> plot3d(sqrt(d2m),a=0..3,t=0.5..2,axes=framed,style=patchcontour,view=[0..3,0.5..2,0..5]):

>

Und als Beschleunigungsvektor

> evalm(5/4*[-1,-3,1]);

[Maple Math]

> # 3VP

>

> ## 11VP

>

>

b)

Dem in P startenden Flugzeug werden nun auch andere Startrichtungen freigegeben, und zwar so, daß der Richtungsvektor der Beschleunigung a2 in der y-Komponente beliebige Wert annehmen kann, also a2 = [-1, ay, 1]. Zeigen Sie, daß das Quadrat des Abstands nun durch folgende Schar dargestellt werden kann...

>

Beschleunigung a2 mit variabler y-Komponente:

> a2:=[-1,ay,1]:

>

Abstandsquadrat

> d2:=dotprod(r1-r2,r1-r2,orthogonal);

[Maple Math]

>

Nach Potenzen von t sortiert

> collect(expand(d2),t);

[Maple Math]

>

> # 2VP

>

>

Zeichnung der Schar

> plot({seq(sqrt(d2),ay=seq(i/3,i=-9..9))},t=-4..4,0..10);

[Maple Plot]

Oder (Monotonie der Wurzelfunktion):

> plot({seq(d2,ay=seq(i/3,i=-9..9))},t=-4..4,0..50);

>

Anm.: Die Laufbereiche der Variablen werden u.U. nicht auf Anhieb geeignet gewählt. Es sollten aber folgende Merkmale sichtbar sein und erörtert werden:

>

> # 2VP # falls eine adäquate Darstellung irgendwo im Worksheet auftaucht

>

>

Die obige Form des Abstandsquadrats zeigt, daß die Koeffizienten von t^4 und t^2 die Anzahl der Extrema bestimmen. Ist der Koeffizient von t^2 Null oder positiv, so ist nur noch ein Extremum (Minimum) möglich (t^4 muß in der gegebenen Situation einen positiver Koeffizienten haben). D.h.:

Kurvenform aus Ordinatenaddition:

> collect(expand(d2),t);

[Maple Math]

>

Die Koeffizienten mit C&P

> solve(-14+6*ay);

[Maple Math]

> solve(5/4-ay+1/4*ay^2);

[Maple Math]

>

- Für welche Werte von ay nimmt die Entfernung der Flugzeuge nach dem Start monoton zu?

Für ay > 7/3 wird also der Koeffizient von t^2 positiv (nur noch ein Minimum für t = 0). Der Koeffizient von t^4 kann nicht Null werden.

>

> # 1VP

>

>

Zweite Möglichkeit:

> textr:=solve(diff(d2,t),t);

[Maple Math]

> solve(-(5-4*ay+ay^2)*(3*ay-7));

[Maple Math]

>

Probe:

> ay:=7/3;

[Maple Math]

> collect(expand(d2),t);

[Maple Math]

>

> ay:='ay':

Also: Für ay >= 7/3 ist der Abstand der Flugplätze der kleinste Abstand. Nach dem Start entfernen sich die Flugzeuge von einander.

>

>

- Für welchen Wert von ay haben die Piloten am längsten Zeit, bis der kleinste Abstand erreicht wird und wie groß ist in diesem Fall der kleinste Abstand?

Die Zeichnung der Schar läßt vermuten, daß der t-Wert der Minima ein Maximum hat (etwa bei t = 3). Zeiten, die für einen extremalen Abstand in Frage kommen:

> textr;

[Maple Math]

>

> tt:=textr[2];

[Maple Math]

>

> plot(tt,ay=-5..7/3,0..3);

[Maple Plot]

>

Extra-VP: Für Beschleunigungen > 7/3 gibt es keinen minimalen Abstand mehr (für Beschl. = 7/3 fallen Min. u. Max zusammen = Abstand beim Start)

>

Die längste Zeit bis zum kürzesten Abstand kann man aus dem Plot ablesen: t = 1.29 bei ay = 2.89. Genauer:

>

> diff(tt,ay);

[Maple Math]

>

Beschleunigungen (ay) für maximale Reaktionszeit

> solve(diff(tt,ay));

[Maple Math]

>

> tmax:=evalf(subs(ay=7/3-1/3*sqrt(10),tt));

[Maple Math]

>

> evalf(subs(ay=7/3+1/3*sqrt(10),tt));

[Maple Math]

(Diese Lösung entfällt.)

>

Minimaler Abstand für maximale Reaktionszeit

> evalf(subs(t=tmax,ay=7/3-1/3*sqrt(10),d2));

[Maple Math]

>

> # 3VP

>

>

Kann es einen Zusamenstoß geben, wenn ay variiert wird? Wenn ja: Wann und wo?

>

Ansätze wie

> solve(d2): # solve(d2,t):, usw.

führen nicht zum Ziel. Wer aber die Kurvenschar 'geeignet' gezeichnet hat, kann vermuten:

> subs(t=2,d2);

[Maple Math]

> subs(t=2,ay=-1,d2);

[Maple Math]

>

> # und das wird als Teillösung akzeptiert!

>

Geometrischer Ansatz:

> r1;r2;

[Maple Math]

[Maple Math]

> d:=evalm(r1-r2);

[Maple Math]

> solve({d[1],d[2]},{t,ay});

[Maple Math]

Probe

> subs(t=2,ay=-1,r2);

[Maple Math]

> subs(t=2,ay=-1,r1);

[Maple Math]

>

Also kommt es für ay = -1 zur Zeit 2 im Punkt Z(0 | 4 | 2) zum Zusammenstoß.

>

> # 2VP

> ## 10VP

>

c)

Für die Beschleunigung des in P startenden Flugzeugs gelte: a2 = [-1,-1,1]. Die Sichtweite beträgt 1. Wieviel Zeit bleibt den Piloten vom ersten Sichtkontakt bis der kleinste Abstand erreicht ist?

> ay:=-1:d2;

[Maple Math]

Einfache Methode, den kleinsten Abstand zu finden (falls der Kollisionskurs im Vorangehenden nicht gefunden wurde):

> plot(d2,t=0..3);

[Maple Plot]

> solve(d2);

[Maple Math]

> textr;

[Maple Math]

So kann man es auch sagen :-))

>

> tsicht:=solve(d2=1,t);

[Maple Math]

>

> evalf(1/5*sqrt(100-5*sqrt(10)));

[Maple Math]

>

Verbleibende Zeit

> evalf(2-1/5*sqrt(100-5*sqrt(10)));

[Maple Math]

>

> # 3VP

>

Unter welchen Winkeln (bezogen auf die eigene Flugrichtung) sieht der Pilot des in P startenden Flugzeugs das andere Flugzeug? Wie läßt sich das Ergebnis interpretieren?

Man bildet den Differenzvektor der beiden Orte

> d:=r1-r2;

[Maple Math]

>

Und berechnet den Winkel zum Richtungsvektor des Flugzeugs P

> cwinkel:=dotprod(d,a2,orthogonal)/(sqrt(innerprod(d,d)*innerprod(a2,a2)));

[Maple Math]

Nicht unbedingt verlangt, aber immer gut für einen Extra-VP

> simplify(cwinkel);

[Maple Math]

> assume(t,real):simplify(cwinkel);

[Maple Math]

>

Wie sieht das aus (mit der experimentellen Mathematik)?

> #plot(cwinkel,t=-3..3);

>

> plot(arccos(cwinkel)/Pi*180,t=-3..3,0..180);

[Maple Plot]

>

> evalf(subs(t=0,arccos(cwinkel)/Pi*180));

[Maple Math]

> evalf(subs(t=3,arccos(cwinkel)/Pi*180));

[Maple Math]

> evalf(subs(t=0,arccos(cwinkel)/Pi*180))+evalf(subs(t=3,arccos(cwinkel)/Pi*180));

[Maple Math]

Da die Flugzeuge (bei geradliniger Bewegung) auf Kollisionskurs liegen, gibt es nur einen Winkel (und seinen Ergänzungswinkel zu 180°). Eine entsprechende Äußerung wird am Horizont erwartet.

>

> # 3VP

>

Zeichnen Sie eine Schar von Strecken, die die beiden Flugzeuge verbinden. Welche Eigenschaft haben diese Strecken (mit Begründung)?

Orte von Flugzeug O und P (was hier relativ trivial aussieht - wenn nämlich vorher alles geklappt hat - ist für einen 'Neueinsteiger' in diesen Aufgabenteil nicht trivial):

> r1p:=seq(r1,t=seq(i/10,i=0..30)):

> r2p:=seq(r2,t=seq(i/10,i=0..30)):

>

Verbindungsstrecken

> strecken:=seq([r1p[i],r2p[i]],i=1..31):

>

> with(plots):

> display(seq(pointplot3d(strecken[i],style=line),i=1..31),axes=normal,scaling=constrained);

[Maple Plot]

>

> # 2VP

>

> evalm(d);

[Maple Math]

In der y-Komponente steht das 3-fache der x-Komponente: Die Differenzvektoren sind kollinear.

>

> # 1VP

> ## 9VP

>