Abi 99

Gebrochen rationale Funktion, Kurvenschar

Dr. M. Komma, Januar 98

Aufgabe

1. Untersuche die Schar .

Anmerkung: Wir stellen eine offene Frage, zu der der Schüler einen 'Eröterungsaufsatz' schreiben kann. Er hat alles, was er dazu braucht, auf seinem Computer zur Verfügung und 3-4 Stunden Zeit. In der folgenden 'Lösung' stehen nicht beantwortete Fragen für mögliche weiterführende Untersuchungen, die der Schüler durchführen könnte, ohne das 'Thema zu verfehlen'.

Heuristik

> restart:

> ft:=x->(4*x^2-t*x+7)/(2*x-2);

>

Mit einer ersten Zeichnung verschafft man sich Überblick.

> plot({seq(ft(x),t=0..10)},x=-2..6,y=-10..10);

Schon auf den ersten Blick kann man vermuten:

1. Die Kurven haben alle die gleiche Definitionslücke.

2. Die Schar hat den gemeinsamen Punkt (0 | - 3.5), soweit sich das mit der Maus im Plot ablesen läßt.

Es entstehen aber auch Fragen:

- Hat jede Kurve genau zwei Extrema?

- Gibt es keine Kurve mit Nullstellen?

- Sehen alle Kurven 'so' aus?

Wir ändern den Laufbereich des Parameters (einfach mal probieren):

> plot({seq(ft(x),t=11..20)},x=-2..6,y=-10..10);

>

Und können die nächsten Vermutungen formulieren:

1. Für gibt es keine Extrema mehr.

2. Für einen besonderen Wert von wird aus der Hyperbel eine Gerade.

3. Der Vorzeichenwechsel beim Pol wird umgekehrt.

4. Es gibt zwei Nullstellen.

Systematische Untersuchung

Wir beginnen mit der näheren Untersuchung:

>

> Z:=numer(ft(x));

> N:=denom(ft(x));

Definitionslücken und Asymptotik

Die Definitionslücke liegt also für alle Kurven bei . Welcher Art ist sie?

Das sieht man am leichtesten, wenn man die Funktion in ihren ganzen und gebrochenen Teil zerlegt:

> convert(ft(x),parfrac,x);

Bevor wir uns mit der Definitionslücke beschäftigen: Die Kurven haben schiefe Asymptoten, mit der Steigung 2, die mit dem Parameter t in vertikale Richtung verschoben werden.

Nun zur Definitionslücke: Für verschwindet der gebrochene Teil und wir erhalten die Gerade

> Asymptote:=convert(subs(t=11,ft(x)),parfrac,x);

mit einer hebbaren Unstetigkeit bei , denn es gilt:

> t:=11:factor(Z);t:='t':

Also

> Hebbare_Unstetigkeit:=[1,subs(x=1,Asymptote)];

>

Was läßt sich für alle anderen Werte von t über den Pol sagen?

> limit(ft(x),x=1);

> limit(ft(x),x=1,right);

> limit(ft(x),x=1,left);

Nullstellen

Wenden wir uns den Nullstellen zu

> solve(Z,x);

>

Für oder sqrt(112.);

>

Gibt es zwei doppelte Nullstellen bei

> abs(x)=solve(subs(t=sqrt(112),ft(x)));

>

Für gibt es zwei Nullstellen, die symmetrisch zu t /8 liegen, und für gibt es keine reellen Nullstellen.

Extrema und Wendepunkte

Wir untersuchen die Existenz von Extrema (ohne hinreichende Bedingung).

>

> fts:=D(ft);

> simplify(fts(x));

> solve(fts(x),x);

Für zwei zur Polstelle symmetrische Extrema. Für fallen die so berechneten Extrema mit der Definitionslücke zusammen und für kann es keine Extrema geben.

>

Warum nicht noch eine Zeichnung?

> plot({seq(ft(x),t=seq(0.05*i+11,i=-10..10))},x=-1..2,y=-5..5);

>

Wir haben noch keine Wendepunkte gesehen.

> ftss:=D(fts);

> simplify(ftss(x));

Es gibt auch keine (die hebbare Unstetigkeit lassen wir nicht als Wendepunkt gelten ;-)

Gemeinsamr Punkt

Wie war das mit dem gemeinsamen Punkt?

> ft(0);

Stimmt!

>

Etwas umständlicher:

> Gemeinsamer_Punkt:=[solve(diff(ft(x),t),x),ft(solve(diff(ft(x),t),x))];

>

Ortskurve der Extrema

Aber Kurvenscharen haben ja noch mehr Merkmale als eventuelle gemeinsame Punkte. Könnte es sein, daß alle Extrema auf einer bestimmten Kurve liegen?

>

> tex:=solve(fts(x),t);

> OK:=simplify(subs(t=tex,ft(x)));

>

> plots[display](plot({seq(ft(x),t=seq(5*i+11,i=-8..2))},x=-4..8,y=-10..40),plot(OK,x=-4..8,y=-10..40,thickness=2,color=black));

>

Seitenthemen

Seitenthemen:

1. Stimmt es, daß die Ortskurve der Extrema durch folgende Punkte gehen muß: Den gemeinsamen Punkt, die doppelten Nullstellen und die hebbare Unstetigkeit?

> subs(x=0,OK);

> subs(x^2=7/4,OK);

> subs(x=1,OK);

>

2. Läßt sich das auch ohne Punktprobe begründen?

3. Muß die Ortskurve der Extrema eine Parabel (Grad 2) sein? Muß diese Parabel symmetrisch zur y-Achse sein?

4. Kann man diese Parabel auch ohne die Ableitung der Funktion berechnen?

>

Isoklinen

Aber eine Ortskurve kommt selten alleine... Die Ortskurve der Extrema ist nur ein Mitglied der Familie der Isoklinen von :

>

> tiso:=solve(fts(x)=c,t);

> Iso:=simplify(subs(t=tiso,ft(x)));

>

> plots[display](plot({seq(ft(x),t=seq(5*i+11,i=-8..2))},x=-4..4,y=-10..40),plot({seq(Iso,c=seq(2*i,i=-8..8))},x=-4..4,y=-10..40,color=black));

Zur Isoklinenschar scheint auch eine Gerade zu gehören...

Und die Isoklinenschar scheint zwei gemeinsame Punkte zu haben (muß das hier so sein?):

>

> collect(Iso,x);

Wer sieht die gemeinsamen Punkte?

>

Die erzeugende DGL

Isoklinen nimmt man gerne zur Veranschaulichung von Differentialgleichungen. Aber wo ist hier eine DGL? Wir können eine machen! Dazu müssen wir nur den Scharparameter eliminieren:

>

> y(x):='y(x)':ys(x):='ys(x)':t:='t':

> sys:=solve({y(x)=ft(x),ys(x)=fts(x)},{t,ys});

>

> assign(%);t:='t':

> DGL:=diff(y(x),x)=ys(x);

Diese DGL erzeugt also unsere Schar. (Was fällt am Nenner der rechten Seite auf?)

>

Wir machen die Probe:

> ### WARNING: `dsolve` has been extensively rewritten, many new result forms can occur and options are slightly different, see help page for details
dsolve(DGL,y(x));

>

Und zeichnen das Richtungsfeld der Differentialgleichung, deren Lösungskurven wir ja schon immer kannten, sowie ein paar Isoklinen:

> Rfeld:=DEtools[dfieldplot]([DGL],[y(x)],x=-4..4,y(x)=-10..40):

> plots[display](Rfeld,plot({seq(Iso,c=seq(4*i,i=-4..4))},x=-4..4,y=-10..40,color=black));

>

So gesehen erscheinen die gemeinsamen Punkte in neuem singulären Licht.

... und auch die Lösungskurven:

> plots[display](Rfeld,plot({seq(ft(x),t=seq(5*i+11,i=-8..2))},x=-4..4,y=-10..40,thickness=2),plot({seq(Iso,c=seq(2*i,i=-8..8))},x=-4..4,y=-10..40,color=black));

>

komma@oe.uni-tuebingen.de