Dr. M. Komma Isolde-Kurz-Gymnasium Reutlingen Januar 98

Abi 99

Leistungskurs Mathematik

Ein Körper wird im homogenen Schwerefeld mit variabler vertikaler Geschwindigkeitskomponente abgeworfen. Die horizontale Geschwindigkeitskomponente sei konstant.

Anmerkung:

Wenn unser Schüler einen Physikkurs belegt hat (oder auch nur in Klasse 11 in Physik aufgepaßt hat), kann er nun mit der Behandlung dieser 'anwendungsorientierten' Aufgabe beginnen.

Der 'reine Mathematiker' bekommt noch einen Tip: Alle möglichen Wurfbahnen können als Überlagerung einer nach unten geöffneten Parabel mit einer Geraden variabler Steigung angesetzt werden.

Lösungsskizze

Heuristik

Eine Skizze zum Hineindenken in die Problemstellung.

> restart:with(plots):with(DEtools):with(geometry):with(plottools):

> l1 := arrow([0,0], [1,0], .03, .06, .05, color=green):
l2 := arrow([0,0], vector([1,1]), .03, .06, .05, color=red):
l3 := arrow([0,0], vector([1,2]), .03, .06, .05, color=red):

> plots[display](l1,l2,l3,scaling=constrained);

>

Eine belebte Skizze.

> li := arrow([0,0], [1,i*0.4], .1, .2, .2, color=red):

> lh := arrow([0,0], [1,0], .1, .2, .2, color=green):

> vani:=plots[display](seq(display(li,lh),i=-10..10),insequence=true,scaling=constrained): vani;

>

So sehen also mögliche Geschwindigkeitsvektoren aus.

Und wie sehen mögliche Bahnen aus?

>

> f:=x->-x^2+t*x;

> Schar:=plot({seq(f(x),t=-4..4)},x=-4..4,-4..4):Schar;

>

Wir sollten das wieder etwas beleben:

> bani:=animate(f(x),x=-4..4,t=-4..4,view=[-4..4,-4..4],color=red,thickness=2,frames=20):bani;

>

> display(vani,bani);

>

>

Da drängt sich einem ja geradezu die Frage auf: "Auf welcher Kurve laufen die Scheitel?" Man könnte dazu die Animation Schritt für Schritt weiterschalten und ein paar Punkte messen. Aber man sieht es eigentlich mit bloßem Auge:

>

> animate({x^2,f(x)},x=-4..4,t=-4..4,view=[-4..4,-4..4],color=red,thickness=2,frames=20);

>

Unser Schüler hat die Gleichung für die Kurvenschar so geschickt gewählt, daß alle Scheitel auf der Normalparabel liegen. Er wird es gleich beweisen.

Details

Isoklinen und gemeinsamer Punkt

Anstatt nur die Ortskurve der Scheitel zu bestimmen, kann man auch gleich die Schar der Isoklinen untersuchen:

> fs:=D(f);

> tiso:=solve(fs(x)=iso,t);

> yiso:=simplify(subs(t=tiso,f(x)));

>

>

> display(plot({seq(f(x),t=-4..4)},x=-4..4,-4..4,color=black),
plot({seq(yiso,iso=-4..4)},x=-4..4,-4..4));

>

Und diese Schar enthält tatsächlich die Normalparabel, wenn nämlich die Steigung ist.

Natürlich hat man schon lange den Ursprung als gemeinsamen Punkt der Schar im Verdacht. Aber ist es auch wirklich der einzige?

> diff(f(x),t);

>

Ja!

Richtungsfeld

Und wenn nun wirklich Pfeile vom Ursprung abgeschossen werden? Wie könnte das aussehen?

Wie das Richtungsfeld einer DG - natürlich der passenden:

> solve({y(x)=-x^2+t*x,diff(y(x),x)=-2*x+t},{diff(y(x),x),t});

>

Also:

> DG:=diff(y(x),x)=y(x)/x-x;

> Feld2:=dfieldplot([DG],[y(x)],x=-4..4,y(x)=-4..4):Feld2;

> display(Feld2,plot({seq(f(x),t=-4..4)},x=-4..4,-4..4,color=black),plot({seq(yiso,iso=-4..4)},x=-4..4,-4..4));

>

Jetzt haben wir die Schar aber voll im Griff - oder?

Singularitäten

Die Pfeile 'kommen' aus einem Punkt. Der gemeinsame Punkt der Integralkurven ist ein singulärer Punkt (Knoten) der DG.

>

> ys:=subs(y(x)=y,rhs(DG));

>

Wenn man die Steigung in einem 3D-Plot darstellt, sieht man noch mehr:

> plot3d(ys,x=-4..4,y=-4..4,axes=framed,view=[-4..4,-4..4,-4..4],style=hidden);

>

Die ganze y-Achse ist singulär!

> limit(ys,x=0,right); limit(ys,x=0,left);

>

Es ist einfach nicht möglich, einen Gegenstand senkrecht hochzuwerfen, wenn die horizontale Geschwindigkeitskomponente nicht 0 ist. (Wo kann so eine Situation vorkommen?)

>

Haben wir auch die richtige DG dargestellt?

> dsolve(diff(y(x),x)=y(x)/x-x,y(x));

> dsolve(diff(y(x),x)=-2*x+t,y(x));

Scheint so.

Felder

Das Richtungsfeld ist ja eine feine Sache, aber man sieht ihm die Geschwindigkeiten nicht an. Das Geschwindigkeitsfeld bietet da noch etwas mehr Information:

> vfeld:=fieldplot([1,y/x-x],x=-2..2,y=-1..2,grid=[10,10],arrows=slim,ytickmarks=2):vfeld;

> display(plot({seq(f(x),t=-4..4)},x=-2..2,-1..2),
vfeld,scaling=constrained,tickmarks=[2,2]);

>

>

Seitenthema

In der Physik hat man es oft mit Feldern in parametrisierter Form zu tun. Das kann bei der Suche nach den Feldlinien zu nicht autonomen Differentialgleichungen führen:

>

> sys:={diff(x(t),t)=1,diff(y(t),t)=y(t)/t-t};

Warum geht (hier) das so ?

>

> sol:=dsolve(sys ,{x(t),y(t)});

>

In Release 5 können nun auch nicht autonome DGln gelöst werden (jedenfalls diese ;-)!

Die Feldlinien haben wir schon gezeichnet, aber wir können sie noch einmal berechnen.

> _C1:=0:

> solve(subs(y(t)=y,x(t)=x,sol),{y,t});

>

Schluss

> c:='c':t:='t':

> pfeil := arrow([t,-t*(t-c)], vector([1,-(2*t-c)]), .2, .4, .2, color=red):

> c:=4:

> p1:=display(seq(display(pfeil),t=seq(0.2*i,i=0..20)),insequence=true,scaling=constrained):

> c:=3:

> p2:=display(seq(display(pfeil,color=blue),t=seq(0.2*i,i=0..20)),insequence=true,scaling=constrained):

> display(p1,p2,title=`bye-bye`);

Kann der rote Pfeil den blauen Pfeil einholen?

>

Release 5 Worksheets können über Maple-Text-Format auch in Release 4 verwendet werden (bis auf wenige Änderungen in der Syntax).

komma@oe.uni-tuebingen.de