Geladene Teilchen in elektromagnetischen Feldern

Aus 'Moderne Physik mit Maple'

c International Thomson Publishing Bonn 1995 filename: newton2.ms

Autor: Komma Datum: 1.5.94

Thema: Newtons Physik, Teilchen in Feldern

Ein Beispiel zur geschlossenen Lösung der Bewegungsgleichung: Ein geladenes Teilchen bewegt sich in kombinierten zeitlich konstanten und homogenen E- und B-Feldern.

Newtons Maschine ist nicht zu stoppen!

> restart;with(linalg):with(student):with(plots):

Warning, new definition for norm

Warning, new definition for trace

> r:=vector([x(t),y(t),z(t)]);

> v:=map(diff,r,t);

> a:=map(diff,v,t);

Definition der Felder:

> El:=vector([Ex,Ey,Ez]);

> B:=vector([Bx,By,Bz]);

Lorentzkraft:

> F:=q*(El+crossprod(v,B));

> evalm(%);

Bewegungsgleichung:

> sys:=equate(m*a,F);

Lösung: (Bitte warten ...)

> sol:=dsolve(sys,{x(t),y(t),z(t)},method=laplace):

> assign(sol);

> xx:=makeproc(x(t),t): yy:=makeproc(y(t),t): zz:=makeproc(z(t),t):

> #xx(t);

Lösungsfunktion (da lacht das Herz des theoretischen Physikers, aber es wäre eine Aufgabe für sich, mit einem CAS und Termmanipulation die relevanten Terme herauszuschälen - siehe Jackson).

> rf:=makeproc(map(eval,r),t): vf:=makeproc(map(eval,v),t): af:=makeproc(map(eval,a),t):

B-Feld in z-Richtung (zur besseren Übersicht):

> Bx:=0:By:=0:

> rf(ZEIT);

Namensgebung:

> x(0):='x0': D(x)(0):='vx0': y(0):='y0': D(y)(0):='vy0':z(0):='z0': D(z)(0):='vz0';

elektrische Feldstärke:

> Ex:=0: Ey:=-5:Ez:=1/10: rf(ZEIT);

Anfangswerte und Konstanten:

> x0:=0: vx0:=0: y0:=0: vy0:=10:z0:=0: vz0:=0:

> q:=1: m:=1: Bz:=2:

Jetzt geht's los!

> myoptions:=axes=normal,labels=['x','y','z'],orientation=[-48,75],scaling=constrained,numpoints=400:

> spacecurve(rf(t),t=0..20,myoptions,color=red,thickness=2);

Aber wer gibt sich schon mit so einem einfachen statischen Bild zufrieden?

> display([seq(spacecurve(rf(t),t=0..i,color=red,thickness=2),i=1..20)],insequence=true,myoptions);

Und schon sind wir mitten in der Elektrodynamik / Magnetohydrodynamik / Relativitätstheorie. Ein Versehen? Nein, das passiert nun einmal, wenn man mit diesen Maschinen arbeitet wie von selbst. Newtons Maschine und die Maple-Maschine verleiten zu einer tour d'horizon durch die Physik. Mit diesem Werkzeug (Maple) kann man das Experiment am Computer durchführen und so "mit Formeln forschen" ... wenn man sie hat und versteht.

Siehe auch: Lagrangepunkte, stabile Orbits und Trojaner

komma@oe.uni-tuebingen.de